Spice model LM741
Uzečemo internu shemu LM741 direktno iz DS.
![[Image: fig3.JPG]](http://3.bp.blogspot.com/_CQoXZjli6hM/TO-4CB5kEvI/AAAAAAAAAiA/d5f2ZrbqC5g/s1600/fig3.JPG)
ULAZ:
-na ulazu imamo cascode differential par ili multistage diff.ulaz, sa preciznim strujnim ogledalom
-u strujnom ogledalu imamo i pinove za offset null funkciju
INTERMEDIUM:
-izmedju preslikavanje struja VASa i ulaznog sklopa
VAS:
-dole u VASu darlington sa limiterom
-izmedju Vbe množač
-gore aktivni CCS
IZLAZ:
-PushPull izlaz sa limiterom
-degeneracija izlaza
Sve u svemu kao malo bolji pojačavač sa diskretnim elementima
Izgleda da je u Netional semi inzenjer za pripremu interne sheme malo cugnuo, pa su se pomešale oznake transistora... no ne smeta! ...ima i dva Q15...
Oznake su na kraju samo oznake, princip i topologija važno da su OK.
Svi transistori sem izlaznih su small signal transistors, nalik NPN BC107 i PNP BC177 , sa H_fe cca 80 - 120,
a izlazni kao nešto jači BC546 i BC556 pa čemo njih uzeti za analizu.
Precrtamo shemu u TinaTI, postavljanjem modela transistora (gornjih).
Sa Text boxom pomognemo si numerirati sva vozlišta svih elementa.
Počnemo naravno sa označbom ulaza,napajanja,izlaza,offset pinova pravilno kao su na TO99 ili DIP8 kučištu po DS.
Tako če nam lakše definisati u simulatoru macro razpored pinova.
Sad možemo napisati model za LM741,
ali bez modela aktivnih transkonduktanca tipa VCCS,
modela naponskih pojačala tipa VCVS ...itd
jer treba puno priprema za takvu analizu da se dobiju podatki za te modele.
Otkucačemo direktno diskretne elemente, sa oznakom vozlišta i tipom elementa, ...i to je to!
Tipa:
Q1 col baza emm tip transistora
primer:
Q1 10 8 7 QXN, transistor Q1 nalazi se: collector na tački 10, baza mu je na 8, dok emmiter na 7, tipa je QX1 kojeg na kraju i opišemo kao model sa svojim parametrima.
Pregledajmo shemu još jednom, označbe vozlišta nesmemo ponavljati, otvaramo NOTEPAD naPCju i pljunimo u ruke:
* 741 OPERATIONAL AMPLIFIER "MACROMODEL" SUBCIRCUIT
* (REV Dragan100 aug2014) max SUPPLY VOLTAGE: +/-15V
* CONNECTIONS:
* NON-INVERTING INPUT
* | INVERTING INPUT
* | | POSITIVE POWER SUPPLY
* | | | NEGATIVE POWER SUPPLY
* | | | | OUTPUT
* | | | | | OFFSET NULL1
* | | | | | | OFFSET NULL2
.SUBCKT LM741N 3 2 7 4 6 1 5
* ULAZNI DEO, CASCODE DIFF + PREC.CURRENT MIRROR + OFFSET NULL PIN 1, 2 *
Q1 8 3 9 QXN
Q2 8 2 10 QXN
Q3 12 11 9 QXP
Q4 13 11 10 QXP
Q5 12 14 1 QXN
Q6 13 14 5 QXN
Q7 7 12 14 QXN
Q8 8 8 7 QXP
R1 1 4 1.001E+3
R2 5 4 1.001E+3
R3 14 4 50.001E+3
*INTERMEDIUM SKLOP*
Q9 11 8 7 QXP
Q10 11 16 15 QXN
Q11 16 16 4 QXN
R4 15 4 4.998E+3
R5 16 17 39.998E+3
Q12 17 17 7 QXP
*VAS + V_BIAS + LIMITER*
Q13 18 17 7 QXP
C1 18 13 30.001E-12
R7 18 19 4.499E+3
R8 19 20 7.499E+3
Q16 18 19 20 QXN
Q17 20 21 22 QXN
Q18 20 13 21 QXN
R12 21 4 49.999E+3
R11 22 4 4.999E+1
Q19 13 22 4 QXN
*IZLAZNI SKLOP + LIMITER*
Q14 7 18 23 QXNN
Q15 18 23 6 QXN
R9 23 6 2.499E+1
R10 6 24 4.999E+1
Q20 4 20 24 QXPP
*MODELI TRANSISTORA QXP, QXN, QXNN I QXPP, DINAMIČKI PARAMETRI!*
.MODEL QXP PNP(Is=336.7f Xti=3 Eg=1.11 Vaf=55.46 Bf=154.4 Ise=412.1f
+ Ne=1.429 Ikf=.2994 Nk=.7028 Xtb=1.5 Br=3.99 Isc=1.03n Nc=1.958
+ Ikr=9.726 Rc=1.833 Cjc=11p Mjc=.2223 Vjc=.5 Fc=.5 Cje=33p
+ Mje=.3333 Vje=.5 Tr=10n Tf=847.7p Itf=2.198 Xtf=23.26 Vtf=10)
.MODEL QXN NPN(Is=7.049f Xti=3 Eg=1.11 Vaf=116.3 Bf=375.5 Ise=7.049f
+ Ne=1.281 Ikf=4.589 Nk=.5 Xtb=1.5 Br=2.611 Isc=121.7p Nc=1.865
+ Ikr=5.313 Rc=1.464 Cjc=5.38p Mjc=.329 Vjc=.6218 Fc=.5 Cje=11.5p
+ Mje=.2717 Vje=.5 Tr=10n Tf=451p Itf=6.194 Xtf=17.43 Vtf=10)
.MODEL QXPP PNP(Is=1.02f Xti=3 Eg=1.11 Vaf=52.31 Bf=306.5 Ise=10.27f
+ Ne=1.764 Ikf=91.85m Nk=.5351 Xtb=1.5 Br=7.437 Isc=1.02f Nc=1.63
+ Ikr=1.7 Rc=1.162 Cjc=9.81p Mjc=.332 Vjc=.4865 Fc=.5 Cje=30p
+ Mje=.3333 Vje=.5 Tr=10n Tf=611.6p Itf=1.37 Xtf=25.92 Vtf=10)
.MODEL QXNN NPN(Is=7.049f Xti=3 Eg=1.11 Vaf=62.79 Bf=374.6 Ise=68f Ne=1.576
+ Ikf=81.57m Nk=.4767 Xtb=1.5 Br=1 Isc=12.4f Nc=1.835 Ikr=3.924
+ Rc=.9747 Cjc=5.25p Mjc=.3147 Vjc=.5697 Fc=.5 Cje=11.5p
+ Mje=.6715 Vje=.5 Tr=10n Tf=410.2p Itf=1.491 Xtf=40.06 Vtf=10)
.ENDS LM741N
*
Modele transistora pronadjemo po net-u, ubacujemo na dno našeg subckt i spreman je za simulaciju.
Pohranimo ga kao LM741.cir
U TinaTi sa New Macro wizardom namestimo novi 741, izmedju treba odabrati shape, i pravilno postavljati pinove ICja...
Postavimo osnovnu shemicu sa non-inverting pojačanjem, naponi napajanja +/-15V, potrošač neka je resistivan od 600 - 1K ohma, postavljamo i 2K trimmer za Offset null štelanje...
Čak ima i "retro" krivu pojačanja, sa baš lepim faznim stavom .. :-)
Tu je i TinaTI fijla.
LM741N.TSC (Size: 9,32 KB / Downloads: 3)
Prijatno :-)
Uzečemo internu shemu LM741 direktno iz DS.
ULAZ:
-na ulazu imamo cascode differential par ili multistage diff.ulaz, sa preciznim strujnim ogledalom
-u strujnom ogledalu imamo i pinove za offset null funkciju
INTERMEDIUM:
-izmedju preslikavanje struja VASa i ulaznog sklopa
VAS:
-dole u VASu darlington sa limiterom
-izmedju Vbe množač
-gore aktivni CCS
IZLAZ:
-PushPull izlaz sa limiterom
-degeneracija izlaza
Sve u svemu kao malo bolji pojačavač sa diskretnim elementima
Izgleda da je u Netional semi inzenjer za pripremu interne sheme malo cugnuo, pa su se pomešale oznake transistora... no ne smeta! ...ima i dva Q15...
Oznake su na kraju samo oznake, princip i topologija važno da su OK.
Svi transistori sem izlaznih su small signal transistors, nalik NPN BC107 i PNP BC177 , sa H_fe cca 80 - 120,
a izlazni kao nešto jači BC546 i BC556 pa čemo njih uzeti za analizu.
Precrtamo shemu u TinaTI, postavljanjem modela transistora (gornjih).
Sa Text boxom pomognemo si numerirati sva vozlišta svih elementa.
Počnemo naravno sa označbom ulaza,napajanja,izlaza,offset pinova pravilno kao su na TO99 ili DIP8 kučištu po DS.
Tako če nam lakše definisati u simulatoru macro razpored pinova.
Sad možemo napisati model za LM741,
ali bez modela aktivnih transkonduktanca tipa VCCS,
modela naponskih pojačala tipa VCVS ...itd
jer treba puno priprema za takvu analizu da se dobiju podatki za te modele.
Otkucačemo direktno diskretne elemente, sa oznakom vozlišta i tipom elementa, ...i to je to!
Tipa:
Q1 col baza emm tip transistora
primer:
Q1 10 8 7 QXN, transistor Q1 nalazi se: collector na tački 10, baza mu je na 8, dok emmiter na 7, tipa je QX1 kojeg na kraju i opišemo kao model sa svojim parametrima.
Pregledajmo shemu još jednom, označbe vozlišta nesmemo ponavljati, otvaramo NOTEPAD naPCju i pljunimo u ruke:
* 741 OPERATIONAL AMPLIFIER "MACROMODEL" SUBCIRCUIT
* (REV Dragan100 aug2014) max SUPPLY VOLTAGE: +/-15V
* CONNECTIONS:
* NON-INVERTING INPUT
* | INVERTING INPUT
* | | POSITIVE POWER SUPPLY
* | | | NEGATIVE POWER SUPPLY
* | | | | OUTPUT
* | | | | | OFFSET NULL1
* | | | | | | OFFSET NULL2
.SUBCKT LM741N 3 2 7 4 6 1 5
* ULAZNI DEO, CASCODE DIFF + PREC.CURRENT MIRROR + OFFSET NULL PIN 1, 2 *
Q1 8 3 9 QXN
Q2 8 2 10 QXN
Q3 12 11 9 QXP
Q4 13 11 10 QXP
Q5 12 14 1 QXN
Q6 13 14 5 QXN
Q7 7 12 14 QXN
Q8 8 8 7 QXP
R1 1 4 1.001E+3
R2 5 4 1.001E+3
R3 14 4 50.001E+3
*INTERMEDIUM SKLOP*
Q9 11 8 7 QXP
Q10 11 16 15 QXN
Q11 16 16 4 QXN
R4 15 4 4.998E+3
R5 16 17 39.998E+3
Q12 17 17 7 QXP
*VAS + V_BIAS + LIMITER*
Q13 18 17 7 QXP
C1 18 13 30.001E-12
R7 18 19 4.499E+3
R8 19 20 7.499E+3
Q16 18 19 20 QXN
Q17 20 21 22 QXN
Q18 20 13 21 QXN
R12 21 4 49.999E+3
R11 22 4 4.999E+1
Q19 13 22 4 QXN
*IZLAZNI SKLOP + LIMITER*
Q14 7 18 23 QXNN
Q15 18 23 6 QXN
R9 23 6 2.499E+1
R10 6 24 4.999E+1
Q20 4 20 24 QXPP
*MODELI TRANSISTORA QXP, QXN, QXNN I QXPP, DINAMIČKI PARAMETRI!*
.MODEL QXP PNP(Is=336.7f Xti=3 Eg=1.11 Vaf=55.46 Bf=154.4 Ise=412.1f
+ Ne=1.429 Ikf=.2994 Nk=.7028 Xtb=1.5 Br=3.99 Isc=1.03n Nc=1.958
+ Ikr=9.726 Rc=1.833 Cjc=11p Mjc=.2223 Vjc=.5 Fc=.5 Cje=33p
+ Mje=.3333 Vje=.5 Tr=10n Tf=847.7p Itf=2.198 Xtf=23.26 Vtf=10)
.MODEL QXN NPN(Is=7.049f Xti=3 Eg=1.11 Vaf=116.3 Bf=375.5 Ise=7.049f
+ Ne=1.281 Ikf=4.589 Nk=.5 Xtb=1.5 Br=2.611 Isc=121.7p Nc=1.865
+ Ikr=5.313 Rc=1.464 Cjc=5.38p Mjc=.329 Vjc=.6218 Fc=.5 Cje=11.5p
+ Mje=.2717 Vje=.5 Tr=10n Tf=451p Itf=6.194 Xtf=17.43 Vtf=10)
.MODEL QXPP PNP(Is=1.02f Xti=3 Eg=1.11 Vaf=52.31 Bf=306.5 Ise=10.27f
+ Ne=1.764 Ikf=91.85m Nk=.5351 Xtb=1.5 Br=7.437 Isc=1.02f Nc=1.63
+ Ikr=1.7 Rc=1.162 Cjc=9.81p Mjc=.332 Vjc=.4865 Fc=.5 Cje=30p
+ Mje=.3333 Vje=.5 Tr=10n Tf=611.6p Itf=1.37 Xtf=25.92 Vtf=10)
.MODEL QXNN NPN(Is=7.049f Xti=3 Eg=1.11 Vaf=62.79 Bf=374.6 Ise=68f Ne=1.576
+ Ikf=81.57m Nk=.4767 Xtb=1.5 Br=1 Isc=12.4f Nc=1.835 Ikr=3.924
+ Rc=.9747 Cjc=5.25p Mjc=.3147 Vjc=.5697 Fc=.5 Cje=11.5p
+ Mje=.6715 Vje=.5 Tr=10n Tf=410.2p Itf=1.491 Xtf=40.06 Vtf=10)
.ENDS LM741N
*
Modele transistora pronadjemo po net-u, ubacujemo na dno našeg subckt i spreman je za simulaciju.
Pohranimo ga kao LM741.cir
U TinaTi sa New Macro wizardom namestimo novi 741, izmedju treba odabrati shape, i pravilno postavljati pinove ICja...
Postavimo osnovnu shemicu sa non-inverting pojačanjem, naponi napajanja +/-15V, potrošač neka je resistivan od 600 - 1K ohma, postavljamo i 2K trimmer za Offset null štelanje...
Čak ima i "retro" krivu pojačanja, sa baš lepim faznim stavom .. :-)
Tu je i TinaTI fijla.
LM741N.TSC (Size: 9,32 KB / Downloads: 3)
Prijatno :-)
LP
Dragan
Dragan