Prakrično igranje sa Tina-TI simulatorom

[Dragan100]

Dragane, primetio sam da je pojačalo dosta brže, ali se pojavio mali overshot.
Ovo su oscilogrami na 1kHz, 5kHz i 10kHz na 1V.

Da li se to čuje, kako se uopšte odražava na zvuk i kako se rešava?

Slaw rate je cca 22-25V/usec @10KHz, za takvog "prcoljku" to je odlično, naravno to su podaci iz simulatora,
u "fuc*ing real world-u" biče naravno nešto slabije...

Mali overshot uopšte ne smeta, taj je meren na izlaznim priklj. pojačala,
ako bi ga merili na prklj. zvučnika več bi bio dampiran.

Tako mali overshot se teško može čuti, jer muzika nisu četvrtke,
neko zbir raznih signala sinusnog tipa i njihovih MEGA -GIGA harmonika,
više duluje (muzika) zveznije i ne tako strogo prekidačko,
ali je četvrtka prava za testiranje sistema!
Kod zveznih signala overshuta skoro nema, jer se pojavljuje samo kod "super" brzih promena velikih amplituda!!!

Inače si treba pogledati malo regulacionu tehniku u elektronici, pogotovo PID regulatore.

U pojačalu taj overshot rešavamo sa kompenzacijama, takozvanim "Miller" efektom u VASu, pa i u predsklopovima,
gdje stavljamo kondenzatore ranga nekoliko desetina pF.

Experimentiši sa promenom vrednosti tog konda,
smanjivanjem dobivaš na brzini, i overshot je jači, pojavljaju se najverovatnije i oscilacije.
Povečavanjem, sasvim obrnuto gornjem, ali zato postaje pojačalo stabilnije a i prava ljenština ... napravili smo iz njega več diferenciator.

LP
Dragan

---

Još jedno pitanje...
Kako da ubacim u simulator LM741 sa svim pinovima? Trebaju mi i offset pinovi a njih nema...

1. Pronači na net-u Spice model za 741 (pogledaj sve proizvodnje) dali ima več model sa ta dva dodatna pina Offset null.
Ubacuješ u TinaTI kao New macro model ...

2.Izabrati Spice model (recimo ovaj od TI.com) i otvoriti .Subckt model (može sa Notepad-om)
LM741 spice model .subckt

*//////////////////////////////////////////////////////////////////////
* © National Semiconductor, Inc.
* Models developed and under copyright by:
* National Semiconductor, Inc.
*/////////////////////////////////////////////////////////////////////
* Legal Notice: This material is intended for free software support.
* The file may be copied, and distributed; however, reselling the
* material is illegal
*////////////////////////////////////////////////////////////////////
* For ordering or technical information on these models, contact:
* National Semiconductor's Customer Response Center
* 7:00 A.M.--7:00 P.M. U.S. Central Time
* (800) 272-9959
* For Applications support, contact the Internet address:
* amps...@galaxy.nsc.com
*//////////////////////////////////////////////////////////
*LM741 OPERATIONAL AMPLIFIER MACRO-MODEL
*//////////////////////////////////////////////////////////
*
* connections:
* non-inverting input
* | inverting input
* | | positive power supply
* | | | negative power supply
* | | | | output
* | | | | |
* | | | | |
.SUBCKT LM741/NS 1 2 99 50 28
*
*Features:
*Improved performance over industry standards
*Plug-in replacement for LM709,LM201,MC1439,748
*Input and output overload protection
*
****************INPUT STAGE**************
*
IOS 2 1 20N
*^Input offset current
R1 1 3 250K
R2 3 2 250K
I1 4 50 100U
R3 5 99 517
R4 6 99 517
Q1 5 2 4 QX
Q2 6 7 4 QX
*Fp2=2.55 MHz
C4 5 6 60.3614P
*
***********COMMON MODE EFFECT***********
*
I2 99 50 1.6MA
*^Quiescent supply current
EOS 7 1 POLY(1) 16 49 1E-3 1
*Input offset voltage.^
R8 99 49 40K
R9 49 50 40K
*
*********OUTPUT VOLTAGE LIMITING********
V2 99 8 1.63
D1 9 8 DX
D2 10 9 DX
V3 10 50 1.63
*
**************SECOND STAGE**************
*
EH 99 98 99 49 1
G1 98 9 5 6 2.1E-3
*Fp1=5 Hz
R5 98 9 95.493MEG
C3 98 9 333.33P
*
***************POLE STAGE***************
*
*Fp=30 MHz
G3 98 15 9 49 1E-6
R12 98 15 1MEG
C5 98 15 5.3052E-15
*
*********COMMON-MODE ZERO STAGE*********
*
*Fpcm=300 Hz
G4 98 16 3 49 3.1623E-8
L2 98 17 530.5M
R13 17 16 1K
*
**************OUTPUT STAGE**************
*
F6 50 99 POLY(1) V6 450U 1
E1 99 23 99 15 1
R16 24 23 25
D5 26 24 DX
V6 26 22 0.65V
R17 23 25 25
D6 25 27 DX
V7 22 27 0.65V
V5 22 21 0.18V
D4 21 15 DX
V4 20 22 0.18V
D3 15 20 DX
L3 22 28 100P
RL3 22 28 100K
*
***************MODELS USED**************
*
.MODEL DX D(IS=1E-15)
.MODEL QX NPN(BF=625)
*
.ENDS
*$


Ili ovaj od Linear technology koji mi se više svidja, pogledati obavezno ovaj PDF


* 741 OPERATIONAL AMPLIFIER "MACROMODEL" SUBCIRCUIT
* (REV N/A) SUPPLY VOLTAGE: +/-15V
* CONNECTIONS:
* NON-INVERTING INPUT
* | INVERTING INPUT
* | | POSITIVE POWER SUPPLY
* | | | NEGATIVE POWER SUPPLY
* | | | | OUTPUT
* | | | | |
.SUBCKT 741 3 2 7 4 6
* INPUT
RC1 7 80 4.3521E+03
RC2 7 90 4.3521E+03
Q1 80 2 10 QM1
Q2 90 3 11 QM2
CIN 2 3 2.0000E-12
C1 80 90 4.5288E-12
RE1 10 12 +2.3917E+03
RE2 11 12 +2.3917E+03
IEE 12 4 2.7512E-05
RE 12 0 7.2696E+06
CE 12 0 7.5000E-12
* INTERMEDIATE
GCM 0 8 12 0 1.1516E-09
GA 8 0 80 90 2.2978E-04
R2 8 0 1.0000E+05
C2 1 8 3.0000E-11
GB 1 0 8 0 3.2110E+01
RO2 1 0 5.6500E+02
* OUTPUT
RSO 1 6 1.0000E+00
ECL 18 0 1 6 3.2808E+01
GCL 0 8 20 0 1.0000E+00
RCL 20 0 1.0000E+01
D1 18 19 DM1
VOD1 19 20 0.0000E+00
D2 20 21 DM1
VOD2 21 18 0.0000E+00
*
D3A 131 70 DM3
D3B 13 131 DM3
GPL 0 8 70 7 1.0000E+00
VC 13 6 2.1831E+00
RPLA 7 70 1.0000E+01
RPLB 7 131 1.0000E+03
D4A 60 141 DM3
D4B 141 14 DM3
GNL 0 8 60 4 1.0000E+00
VE 6 14 3.6831E+00
RNLA 60 4 1.0000E+01
RNLB 141 4 1.0000E+03
*
IP 7 4 1.9525E-03
DSUB 4 7 DM2
* MODELS
.MODEL QM1 NPN (IS=8.0000E-16 BF=5.2662E+01)
.MODEL QM2 NPN (IS=8.0928E-16 BF=5.2807E+01)
.MODEL DM1 D (IS=1.0000E-20)
.MODEL DM2 D (IS=8.0000E-16 BV=4.8000E+01)
.MODEL DM3 D (IS=1.0000E-16)
.ENDS 741
*
U DS LM741 pronadjemo internu shemu ICja, strana 4 - SCHEMATIC DIAGRAM

Ulaz sačinjava diff.input, emmiteri su spojeni na precizan CCS koji završava sa otpornicima R1 i R2 (oba 1K) na -Vee, tu su nam traženi Offset null pinovi!

Sad pogledajmo shemu koju su priložili LT u PDFju (gore sam postavio link) strana 7 slika (figure) 4B

CCS sačinjava idealni strujni izvor -IEE (u ovom primeru ponor) koji je vezan na -Vee i na oba emmiterska otpornika RE1 i RE2 ulaznog diff.sklopa.

Offset null 1 i 2 mogli bismo ugurati direktno na spojeve tih dviju otpornika spojenih svaki na svoj emmiter.
To bi bila zadovoljavajuča aproksimacija tog macro modela, ali mi bi željeli preciznije... :-)

Nas sada interesuje INPUT sekcija da možemo pronači mesta Offset null1 (pin 1) i Offset null 2 (pin 5)

iz .subckt pogledajmo si input sekciju:
* INPUT
RC1 7 80 4.3521E+03
RC2 7 90 4.3521E+03
Q1 80 2 10 QM1
Q2 90 3 11 QM2
CIN 2 3 2.0000E-12
C1 80 90 4.5288E-12
RE1 10 12 +2.3917E+03
RE2 11 12 +2.3917E+03
IEE 12 4 2.7512E-05
RE 12 0 7.2696E+06
CE 12 0 7.5000E-12

RE1 i RE2 naše su mete, ali sada treba ugurati još dva otpornika i dve nove interne priključne tačke.
Imamo:
RE1 = RE2 = +2.3917E+03
dodačemo:
RE3 = RE4 = +1.0001E+03
a RE1 = RE2 adekvatno smanjujemo
RE1 = RE2 = +1.3916E+03
-----------------------------
RE1 stari = RE1 novi + RE3, slično i za RE2 novi
naravno, treba u .subckt preveriti dali nije več upotrebljen otpornik sa takvom oznakom!
-----------------------------
Sad treba definirati i nove interne priključne tačke, koje jasno nisu več upotrebljene (oznake),
prečekiramo opet celi .subckt, i dodajemo dve nove oznake koje nisu upotrebljene , 13 i 14

Ubacujemo u novi .subckt
* INPUT (NOVI)
RC1 7 80 4.3521E+03
RC2 7 90 4.3521E+03
Q1 80 2 10 QM1
Q2 90 3 11 QM2
CIN 2 3 2.0000E-12
C1 80 90 4.5288E-12
RE1 10 13 +1.3916E+03
RE2 11 14 +1.3916E+03
RE3 13 12 +1.0001E+03
RE4 14 12 +1.0001E+03
IEE 12 4 2.7512E-05
RE 12 0 7.2696E+06
CE 12 0 7.5000E-12

Praktički ništa nismo promenili shematski, sve vrednosti ostaju iste kao u originalnom macru,
ali sada imamo tačku 13 koja predstavlja pin 1 OFFSET NULL1 i tačku 14 koja predstavlja pin 5 Offset null2.

Sad nam preostaje samo da definišemo u .subckt ova dva nova priključka:

* CONNECTIONS:
* NON-INVERTING INPUT
* | INVERTING INPUT
* | | POSITIVE POWER SUPPLY
* | | | NEGATIVE POWER SUPPLY
* | | | | OUTPUT
* | | | | | OFFSET NULL1
* | | | | | | OFFSET NULL2
.SUBCKT 741 3 2 7 4 6 13 14

Sada ubacujemo u novi .subckt * CONNECTIONS i * INPUT (NOVI)
i upotrebljiv je kao macro sa Offset null pinovima!

:-)


LP
Dragan